Çözüldü Alt Alta Yazılı Sayıların Sonuncusunu Çekme

E

Epakambalaj

Normal Üye
Excel Versiyonu
Excel 2016
Excel Sürümü
64 Bit
Excel Dili
Türkçe
Hayırlı günler üstadlarım.

Örnek: D30 Hücresinde 48 yazıyor
D60 Hücresinde 12 yazıyor
D90 Hücresi Henüz boş
D120 Hücresi Henüz boş

Bu Mantıkla Alt Alta Devam Eden (Sadece Belirlenmiş) Seçili Hücrelerin En Alttaki Dolu Hücresindeki Veriyi D4951 hücresine çekmek istiyoruz.
Yardımcı olabilir misiniz?

Şimdiden çok teşekkür ediyorum :)
 
Tarihe göre sırala Oylamaya göre sırala
Selamlar,
Sorunuzdan anladığımı aktarayım....
Varsayıyorum D5 : D300 arasında en son SAYI yazan hücrenin içeriğini alacaksınız.
** Koşulunuz ise her 30. satır
Yani 30., 60., 90., 120, 150, 180,.....300. satırlardan en son hangisinde SAYI yazıyorsa o değer alınacak....

D kolonu hariç herhangi bir hücreye
=ARA(2;1/(MOD(SATIR($D$5:$D$300);30)=0)/(ESAYIYSA($D$5:$D$300));$D$5:$D$300)

formülünü yazın.
 
Oyla 0 Olumsuz oyla
52779' Alıntı:
Selamlar,
Sorunuzdan anladığımı aktarayım....
Varsayıyorum D5 : D300 arasında en son SAYI yazan hücrenin içeriğini alacaksınız.
** Koşulunuz ise her 30. satır
Yani 30., 60., 90., 120, 150, 180,.....300. satırlardan en son hangisinde SAYI yazıyorsa o değer alınacak....

D kolonu hariç herhangi bir hücreye
=ARA(2;1/(MOD(SATIR($D$5:$D$300);30)=0)/(ESAYIYSA($D$5:$D$300));$D$5:$D$300)

formülünü yazın.
Genişletmek için tıklayın ...
Gerçek hücrelere uyarlamaya çalıştım yapamadım :)

Gerçek Hücreler

D29
D62
D95

şeklinde 150 hücre 33er atlayarak son hücre olan 4946 da bitiyor.

Nasıl yapabiliriz?
 
Oyla 0 Olumsuz oyla
52779' Alıntı:
Örnek dosya ekleseniz çok daha çabuk çözüme ulaşırsınız.

Yine anladığım şekilde cevap vereyim.

=ARA(2;1/(MOD(SATIR($D$5:$D$4946)+4;33)=0)/(ESAYIYSA($D$5:$D$4946));$D$5:$D$4946)
Genişletmek için tıklayın ...
hayırlı günler üstadım.
formul gereği arama içerisinde kalan 150 hücre içerisinde "0" sonucu var.
bize tamamında "0" olan hücrelerin içerisinde, "0" üzerinde olan en son rakam lazım

Ör.
D29 15 tl
D62 40 tl
D95 18 tl
D128 0 tl
D161 0 tl
.... D4946 0 tl
şeklinde olan tabloda "0" üzerinde olan en son rakam olarak 18 tl'yi almak istiyoruz. Nasıl yapabiliriz?

Çok Teşekkür Ediyorum.
 
Oyla 0 Olumsuz oyla
Selamlar,
Formüle bir koşul daha eklemek gerekir.

=ARA(2;1/(MOD(SATIR($D$5:$D$4946)+4;33)=0)/(ESAYIYSA($D$5:$D$4946))/($D$5:$D$4946<>0);$D$5:$D$4946)

Formülün anlamı da şu :
1 - D5 hücresinden itibaren, (D5 5. satır olmakta) satırlara 4 ekle.
2 - Her 33 satırda bir olan değerlere bak..
(D5. 5 satır, D29 ise 29. satır... 4 eklersek 29 + 4 =33 yani 29. satır 4 eklenince 33 olup MOD(29+4;33) = 0 olacaktır. (Diğer bir deyişle 29 +4, 33 e kalansız bölünür)..... Yani 29. satır aranılan satır olmakta. Diğer bir örnek ise D62 yani 62. satır 62 + 4 =66 olup 33 e kalansız bölünür. Yani 62. satır da koşulu sağlamaktadır)
3 - ESAYIYSA($D$5:$D$4946) bir koşuldur.... 29, 62, 95 gibi satır no olarak SATIR koşulunu sağlayanlar için hücre içeriklerinin SAYI olması na bakılır.
4 - Şimdi bir koşulunuz daha var... Bakılan hücrelerde 0 olabilir... Evet 0 sayıdır. Ama 0 değerlerinin olmamasını istiyoruz. O nedenle bir koşul daha ekliyoruz. ($D$5:$D$4946<>0) ile bakılana hücrelerin 0 olmamasını istiyoruz.
5 - ;$D$5:$D$4946 ile de tüm koşulları sağlayan hücre değerlerini alıyoruz..... Yani (D29;D62;D95;D128;... bakıyoruz... SAYI olup 0 olmayanlar dizi olarak şöyle oluyor...(Örneğinize göre) {15;40;18}
6 - ARA(2;1 / ile de en son SAYI olan D95 hücresindeki 18 yazılacaktır....

Not : Ben 0 dan farklı şeklinde yazdım koşulu.... NEGATİF yani 0 dan küçük sayılar varsa koşulu sağlayacaktır... Aradığınız 0 dan büyükler ise ($D$5:$D$4946>0) şeklinde yazınız..
 
Oyla 0 Olumsuz oyla
52779' Alıntı:
Selamlar,
Formüle bir koşul daha eklemek gerekir.

=ARA(2;1/(MOD(SATIR($D$5:$D$4946)+4;33)=0)/(ESAYIYSA($D$5:$D$4946))/($D$5:$D$4946<>0);$D$5:$D$4946)

Formülün anlamı da şu :
1 - D5 hücresinden itibaren, (D5 5. satır olmakta) satırlara 4 ekle.
2 - Her 33 satırda bir olan değerlere bak..
(D5. 5 satır, D29 ise 29. satır... 4 eklersek 29 + 4 =33 yani 29. satır 4 eklenince 33 olup MOD(29+4;33) = 0 olacaktır. (Diğer bir deyişle 29 +4, 33 e kalansız bölünür)..... Yani 29. satır aranılan satır olmakta. Diğer bir örnek ise D62 yani 62. satır 62 + 4 =66 olup 33 e kalansız bölünür. Yani 62. satır da koşulu sağlamaktadır)
3 - ESAYIYSA($D$5:$D$4946) bir koşuldur.... 29, 62, 95 gibi satır no olarak SATIR koşulunu sağlayanlar için hücre içeriklerinin SAYI olması na bakılır.
4 - Şimdi bir koşulunuz daha var... Bakılan hücrelerde 0 olabilir... Evet 0 sayıdır. Ama 0 değerlerinin olmamasını istiyoruz. O nedenle bir koşul daha ekliyoruz. ($D$5:$D$4946<>0) ile bakılana hücrelerin 0 olmamasını istiyoruz.
5 - ;$D$5:$D$4946 ile de tüm koşulları sağlayan hücre değerlerini alıyoruz..... Yani (D29;D62;D95;D128;... bakıyoruz... SAYI olup 0 olmayanlar dizi olarak şöyle oluyor...(Örneğinize göre) {15;40;18}
6 - ARA(2;1 / ile de en son SAYI olan D95 hücresindeki 18 yazılacaktır....

Not : Ben 0 dan farklı şeklinde yazdım koşulu.... NEGATİF yani 0 dan küçük sayılar varsa koşulu sağlayacaktır... Aradığınız 0 dan büyükler ise ($D$5:$D$4946>0) şeklinde yazınız..
Genişletmek için tıklayın ...
ellerinize sağlık üstadım.
çok teşekkür ediyorum.
 
Oyla 0 Olumsuz oyla
Yanıt için giriş yapmanız veya üye olmanız gerekir.

Benzer Konular Popüler Daha Fazlası

Üst