Bir Yıldaki Haftanın Günlerini Sayma

Microsoft Excel, tarihler ve zaman aralıkları üzerinde çalışırken kullanıcılarına mükemmel bir esneklik sunar. Özellikle, bir yıl içinde belirli bir haftanın gününün kaç kez geçtiğini belirlemek gibi özel ihtiyaçlar için oldukça faydalıdır. Bu makalede, bu işlemi Excel'de nasıl gerçekleştireceğinizi adım adım öğreneceksiniz.

Excel ile Haftanın Günlerini Sayma​

Belirli bir yılda, örneğin Pazartesi gününün kaç kez geçtiğini öğrenmek için aşağıdaki adımları takip edebilirsiniz.

Adım 1: Yılı Belirleyin​

Öncelikle, analiz etmek istediğiniz yılı A1 hücresine girin. Örneğin: "2023".

Adım 2: Hedef Günü Tanımlayın​

B1 hücresine, sayısını belirlemek istediğiniz günü yazın. Örneğin: "Pazartesi".

Adım 3: Formülü Uygulayın​

B2 hücresine aşağıdaki formülü girin:
Kod: 
=TOPLA(EĞER(HAFTANINGÜNÜ(TARİH(A1;1;SATIR(DOLAYLI("1:365"))))=EĞER(B1="Pazartesi";2;EĞER(B1="Salı";3;EĞER(B1="Çarşamba";4;EĞER(B1="Perşembe";5;EĞER(B1="Cuma";6;EĞER(B1="Cumartesi";7;EĞER(B1="Pazar";1;0)))))));1;0))
Bu formül, seçilen yılda belirtilen günün kaç kez geçtiğini döndürecektir.

Eğer, Excel 365 kullanıyorsanız, formülü biraz daha farklı olarak aşağıdaki gibi deneyebilirsiniz:
Kod: 
=TOPLA(EĞER(HAFTANINGÜNÜ(TARİH(A1;1;SIRALI(365)))=EĞER(B1="Pazartesi";2;EĞER(B1="Salı";3;EĞER(B1="Çarşamba";4;EĞER(B1="Perşembe";5;EĞER(B1="Cuma";6;EĞER(B1="Cumartesi";7;EĞER(B1="Pazar";1;0)))))));1;0))

Ek Bilgiler ve İpuçları​

Artık Yıllar​

Artık yıllarda Şubat ayı 29 gün olduğu için, 366 gün üzerinden hesaplama yapmanız gerektiğini unutmayın.

Dil ve Bölgesel Ayarlar​

Bu makalede kullanılan formül, Türkçe Excel sürümü için uygundur. Farklı dillerde veya sürümlerde fonksiyon isimleri veya haftanın günleri için kullanılan değerler değişiklik gösterebilir.
 

Ekli dosyalar

Genişletmek için tıklayın ...
365 - 366 gün olayı için formül güncelleme gerekli değil.
Birinci formül eski versiyonlar için, ikinci formül excel 365 için.

Kod: 
=TOPLA.ÇARPIM(--(METNEÇEVİR(SATIR(DOLAYLI("A"&TARİH(A1;1;1)&":A"&TARİH(A1;12;31)));"gggg")=B1))
=TOPLA.ÇARPIM(--(METNEÇEVİR(SIRALI(TARİH(A1;12;31)-TARİH(A1;1;1)+1;;TARİH(A1;1;1));"gggg")=B1))
 
365 ile bir alternatif daha olsun

Kod: 
=LET(i;A1;x;"31.12."&i;y;"1.1."&i;TOPLA(--(METNEÇEVİR(SIRALI(x-y+1;;y);"gggg")=B1)))
 
TAMİŞGÜNÜ.ULSL işleviyle alternatif olsun.
B1 hücresinde Pazartesi için KOD : 0111111
Kod: 
=TAMİŞGÜNÜ.ULUSL(TARİH(A1;1;1);TARİH(A1;12;31);"0111111")
Eğer ki, B1 hücresi için kodu da formüle edeceksek
Kod: 
=TAMİŞGÜNÜ.ULUSL(TARİH(A1;1;1);TARİH(A1;12;31);TABAN(127-2^(7-KAÇINCI(B1;METNEÇEVİR(SIRALI(;7;2);"gggg");));2;7))
ya da
Kod: 
=TAMİŞGÜNÜ.ULUSL(TARİH(A1;1;1);TARİH(A1;12;31);DEĞİŞTİR("1111111";KAÇINCI(B1;METNEÇEVİR(SIRALI(;7;2);"gggg"););1;0))
 
Yanıt için giriş yapmanız veya üye olmanız gerekir.

Benzer Konular Popüler Daha Fazlası

Üst