Tekrar Eden Verileri Tek Sayma

merakli · 17 Şub 2021

Resimdeki gibi bir tabloda Tekrar eden ders isimlerini 1 defa saydırarak toplam ders sayısını nasıl alabiliriz

Fen - Fen - Matematik - Matematik - Müzik - Türkçe - Türkçe
şeklinde hücrelerimiz var

Fen dersi 2 defa ama tekrar ettiği için 1 defa sayılacak
Matematik dersi 2 defa ama tekrar ettiği için 1 defa sayılacak
Müzik dersi tekrar etmiyor zaten bir tane olduğu için 1 defa sayılacak
Türkçe dersi 2 defa ama tekrar ettiği için 1 defa sayılacak
Toplam sonucumuz : 4 şeklinde çıkacak

Bunu formülle nasıl yapabiliriz?

52779 · 17 Şub 2021

Selamlar,
Dosyanıza göre H1 hücresine

=TOPLA.ÇARPIM(1/EĞERSAY($A$1:$G$1;$A$1:$G$1))

formülünü yazınız.

serkoloji · 17 Şub 2021

Sanırım istediğiniz bu.

merakli · 17 Şub 2021

Teşekkürler.

merakli · 17 Şub 2021

merakli · 17 Şub 2021

52779 hocam yeni bir oluştu.
Arada bir ya da bir kaç boş hücre olduğunda boş olmayanları saymaması için nasıl bir değişiklik yapmak lazım bu kodda

52779 · 17 Şub 2021

D1, F1 ve H1 BOŞ olsun...(Sizin dosyada bir adet vardı ben 3 adet önereyim)

Dolayısıyla verileriniz... A1 : J1 aralığında

K1 hücresine
=TOPLA.ÇARPIM(1/EĞERSAY($A$1:$J$1;$A$1:$J$1&""))
formülünü yazarsanız sonuç 4 yerine 5 çıkacaktır. Çünkü BOŞ da benzersiz olacaktır.

BOŞ değerini saymazsak eğer
=TOPLA.ÇARPIM(1/EĞERSAY($A$1:$J$1;$A$1:$J$1&""))-1
şeklinde formülü yazınız....

merakli · 17 Şub 2021

Teşekkür ederim Topla.Çarpımın böyle kullanıldığını ilk defa gördüm.
Ancak şöyle bir durum ortaya çıktı şimdide

=TOPLA.ÇARPIM(1/EĞERSAY($A$1:$J$1;$A$1:$J$1&""))-1
Bunu kullandığımızda boş hücre varsa tamam ama boş hücre yokssa bu defa doğru sonuçtan bir eksiltiyor

52779 · 17 Şub 2021

=TOPLA.ÇARPIM(1/EĞERSAY($A$1:$J$1;$A$1:$J$1&""))-(BOŞLUKSAY($A$1:$J$1)>0)

merakli · 17 Şub 2021

Şimdi kaçacak yeri kalmadı

Teşekkürler

52779 · 17 Şub 2021

Yukarıda verdiğim formülü şu şekilde de kullanabilirsiniz.

=TOPLA.ÇARPIM((A1:J1<>"")/EĞERSAY($A$1:$J$1;$A$1:$J$1&""))

Ekleme :
(A1:J1<>"") ifadesinde hücre aralığını sabitlemek gerekebilir. Yani ($A$1:$J$1<>"") şeklinde....

Dosyanızı da ekliyorum...

merakli · 12 Mar 2025

Teşekkürler.
Emeğinize sağlık

	Tekrar eden verileri tek getirme selis 1 Haz 2022 Formül Soruları
	Tekrar Eden Verileri Listeleme Ömer BARAN 2 May 2024 Formül Soruları
	En Fazla Tekrar Eden Sayi Çiftleri cakarem 10 Mar 2022 Formül Soruları
	En Çok Tekrar Eden Sayıyı Bulma ExcelDepo 6 Kas 2021 Formül Soruları
	Tarihe Göre Tekrarsız Listeleme PriveT 18 Mar 2025 Formül Soruları