I

Çözüldü Formüllerdeki Değerleri Nasıl Ardışık Artırabilirim

I

ikayserili

Normal Üye
Excel Versiyonu
Excel 2016
Excel Sürümü
64 Bit
Excel Dili
Türkçe
Merhaba

Başka sayfadan diğer sayfaya veri çektirmem gerekiyor. Otomatik kendisi yapması için her hücreye formül eklemem gerekiyor.
Hücrelerim ilk sayfada 2'şer li şekilde arttığı için formül yazarken zor oluyor.
Formülüm:
=EĞER('Bilgi Girişi'!P48="3AWG SWALLOW";'Bilgi Girişi'!Q48;EĞER('Bilgi Girişi'!P48="1/0 RAVEN";'Bilgi Girişi'!Q48;EĞER('Bilgi Girişi'!P48="3/0 PIGEON";'Bilgi Girişi'!Q48;EĞER('Bilgi Girişi'!P48="477.0MCM HAWK";'Bilgi Girişi'!Q48;EĞER('Bilgi Girişi'!P48="LİSTEDE OLMAYAN DEMİR";'Bilgi Girişi'!Q48;"")))))

Buradaki P48 ve Q48 değerleri bir sonraki hücrede 50 sonra 52 olacak. Şu an için en son 234 'de bitireceğim. Tek tek formül'deki rakamları değiştirmek zor oluyor. ve formül uzadıkça baya zahmetli olmaya başladı.
Hücrenin sağ alt köşesine gelince mause + ifadesi olup aşağı çekince istediğim sonuca ulaşamıyorum.
tek tek uğraşmak baya yordu. Kolay bir yolu var mı ?
 
Tarihe göre sırala Oylamaya göre sırala
Selamlar,

'Bilgi Girişi'!P48 yerine,
DOLAYLI("'Bilgi Girişi'!P"&48+2*(SATIR($A1)-1))
'Bilgi Girişi'!Q48 yerine,
DOLAYLI("'Bilgi Girişi'!Q"&48+2*(SATIR($A1)-1))

şeklinde yazın deneyin....

Not : Formülünüzden anladığım,
'Bilgi Girişi'!P48, "3AWG SWALLOW", "1/0 RAVEN", "3/0 PIGEON", "477.0MCM HAWK", "LİSTEDE OLMAYAN DEMİR" den birisi olduğunda 'Bilgi Girişi'!Q48 değeri yazılacak.
Bu durumda formülünüzü sadeleştirebilirsiniz...

=EĞER(DOLAYLI("'Bilgi Girişi'!P"&48+2*(SATIR($A1)-1))={"3AWG SWALLOW";"1/0 RAVEN";"3/0 PIGEON";"477.0MCM HAWK";"LİSTEDE OLMAYAN DEMİR"};DOLAYLI("'Bilgi Girişi'!Q"&48+2*(SATIR($A1)-1));"")

ya da

=EĞER(ESAYIYSA(KAÇINCI(DOLAYLI("'Bilgi Girişi'!P"&48+2*(SATIR($A1)-1));{"3AWG SWALLOW";"1/0 RAVEN";"3/0 PIGEON";"477.0MCM HAWK";"LİSTEDE OLMAYAN DEMİR"};0));DOLAYLI("'Bilgi Girişi'!Q"&48+2*(SATIR($A1)-1));"")

şeklinde....
 
Oyla 0 Olumsuz oyla
Yanıt için giriş yapmanız veya üye olmanız gerekir.
Üst