TOPLAMA

=TOPLAMA(işlev_num; seçenekler; dizi; [k])
=TOPLAMA(işlev_num; seçenekler; başv1; ...)

=AGGREGATE(function_num; options; array; [k])
=AGGREGATE(function_num; options; ref1, ...)

AÇIKLAMA

Listede veya veritabanında bir toplam verir. TOPLAMA formülü, gizli satırları ve hata değerlerini yoksayma seçeneğiyle birlikte listeye veya veritabanına farklı toplama işlevleri uygulayabilir.

AMAÇ

Seçtiğiniz kritere bağlı toplam hesaplama.

SONUÇ DEĞERİ

Belirtilen işleve bağlıdır

SÖZ DİZİMİ

Başvuru Biçimi

=TOPLAMA(işlev_sayısı;seçenekler;başv1;[başv2];…)

Dizi biçimi

=TOPLAMA(işlev_sayısı;seçenekler;dizi;[k])

ARGÜMANLAR

işlev_num - işlevi belirten 1 - 19 arası bir sayı.
Seçenekler - İşlevle ilgili değerlendirme aralığında hangi değerlerin yoksayılacağını saptayan sayısal değer.
başv1 - Değerlerini toplamak istediğiniz birden çok bağımsız değişkeni alan ilk sayısal bağımsız değişken.
başv2 - İsteğe Bağlı - Değerlerini toplamak istediğiniz 2 - 253 arası sayısal bağımsız değişkenler.

KULLANIMI

TOPLAMA formülü, ORTALAMA, SAYMA, MAKSİMUM, MİNİMUM vb. toplu bir hesaplamanın sonucunu döndürür. Toplam 19 işlem mevcuttur ve gerçekleştirilecek işlem, işlevde ilk bağımsız değişken olarak görünen bir sayı olarak belirtilir. İkinci argüman, seçenekler, TOPLAMA'nın gizli satırlardaki hataları ve değerleri nasıl işlediğini kontrol eder. Mevcut tüm seçenekler için en alttaki tabloyu inceleyebilirsiniz.

ÖRNEKLER

TOPLAMA Örnek Tablosu

TOPLAMA formülü ile yapacağımız bazı formüller için üstteki gibi basit bir tablo yaptık ve örneklerimizde referans olarak kullanacağız.

Örnek 1

Hem hataları hem de gizli satırları yok sayarak B4:B14 aralığındaki MAKSİMUM değerini döndürmek için işlev numarası için 4, seçenekler için 7 yazın:

=TOPLAMA(4;7;$B$5:$B$14)

Aynı seçeneklerle MİNİMUM değeri döndürmek için işlev numarasını 5 olarak değiştirin:

=TOPLAMA(5;7;$B$5:$B$14)

Örnek 2

Tabloya göre hatalı değerleri dikkate almadan MAKSİMUM değeri bulmak için formül aşağıdaki gibidir:

=TOPLAMA(4;6;$B$5:$B$14)

6 numaralı kod, yalnızca hataları göz ardı etmek için kullanılmıştır.

Örnek 3 X'inci Büyük

Alttaki formülleri alt alta yazarak "X'inci en büyük" değerlerin nasıl bulunacağını gözlemleyebilirsiniz.

=TOPLAMA(14;6;$B$5:$B$14;1)
=TOPLAMA(14;6;$B$5:$B$14;2)
=TOPLAMA(14;6;$B$5:$B$14;3)

X sıradaki en büyük değeri bulmak hiç bu kadar kolay olmamıştı.

Örnek 4 Diziler

TOPLAMA formülünü, daha karmaşık formüller için özellikle yararlı kılan şey, işlev numarası 14-19 olduğunda dizileri yerel olarak işleyebilmesidir. Örneğin, tarihler ve değerler içeren verilerle Pazartesi günleri MAKSİMUM değerini bulmak için TOPLAMA formülünü şu şekilde kullanabilirsiniz:

=TOPLAMA(14;6;$B$5:$B$14/(METNEÇEVİR($C$5:$C$14;"gggg")="Pazartesi");1)

Burada fonksiyon için 14 (BÜYÜK) ve seçenek için 6 (hata değerlerini yoksay) belirtiyoruz. Ardından, Pazartesi günleri için tüm tarihleri kontrol etmek amacıyla METNEÇEVİR formülünü kullanarak mantıklı bir ifade oluşturuyoruz. Bu işlemin sonucu, orjinal değerlerin paydası haline gelen bir DOĞRU / YANLIŞ değerler dizisidir. YANLIŞ, sıfır olarak değerlendirilir ve bir #SAYI/0! hatası verir. DOĞRU, 1 olarak değerlendirilir ve orijinal değeri döndürür. Son değerler ve hatalar dizisi bir filtre gibi davranır. TOPLAMA, tüm hataları yok sayar ve kalan değerlerin en büyüğünü (MAKSİMUM) döndürür.

Üstteki formülü kullandığımız X Güne Ait En Küçük Değeri Bulma ve X Güne Ait En Büyük Değeri Bulma isimli dosyalarımızı inceleyebilirsiniz.

İŞLEV NUMARALARI

Aşağıdaki tablo, TOPLAMA formülü için kullanılabilen işlev numaralarını, ilişkili formüllerin adıyla birlikte listeler. Üçüncü sütun Başv2, gerektiğinde beklenen ikinci bağımsız değişken değerini gösterir.

İşlev Numarası Formül Adı Başv2
1 ORTALAMA
2 BAĞ_DEĞ_SAY
3 BAĞ_DEĞ_DOLU_SAY
4 MAK
5 MİN
6 ÇARPIM
7 STDSAPMA.S
8 STDSAPMA.P
9 TOPLA
10 VAR.S
11 VAR.P
12 ORTANCA
13 ENÇOK_OLAN.TEK
14 BÜYÜK k
15 KÜÇÜK k
16 YÜZDEBİRLİK.DHL k
17 DÖRTTEBİRLİK.DHL dörttebir
18 YÜZDEBİRLİK.HRC k
19 DÖRTTEBİRLİK.HRC dörttebir

DAVRANIŞ SEÇENEKLERİ

Seçenek Davranış
0 İç içe ALTTOPLAM ve TOPLAMA işlevleri yoksayılır.
1 Gizli satırlar, iç içe ALTTOPLAM ve TOPLAMA işlevleri yoksayılır.
2 Hata değerleri, iç içe ALTTOPLAM ve TOPLAMA işlevleri yoksayılır.
3 Gizli satırlar, hata değerleri, iç içe ALTTOPLAM ve TOPLAMA işlevleri yoksayılır.
4 Hiçbir şey yoksayılmaz.
5 Gizli satırlar yoksayılır.
6 Hata değerleri yoksayılır.
7 Gizli satırlar ve hata değerleri yoksayılır

NOTLAR

TOPLAMA formülü, veri sütunları veya dikey aralıklar için tasarlanmıştır. Veri satırları veya yatay aralıklar için tasarlanmamıştır. Örneğin, seçenek 1'i kullanarak bir yatay aralığın alt toplamını aldığınızda (örneğin, topla (1, 1, Başv1), sütunu gizlediğinizde toplam toplam değeri etkilenmez. Ancak dikey aralıkta bir satırı gizlemek toplamayı etkiler.

Dizi alan işlevler için başv1 dizi, dizi formülü veya değerlerini toplamak istediğiniz hücre aralığı referansıdır. Başv2 bazı işlevler için gereken ikinci bağımsız değişkendir. Aşağıdaki işlevler için başv2 gerekir:

BÜYÜK(dizi,k)
KÜÇÜK(dizi,k)
YÜZDEBİRLİK.DHL(dizi,k)
DÖRTTEBİRLİK.DHL(dizi,dörttebir)
YÜZDEBİRLİK.HRC(dizi,k)
DÖRTTEBİRLİK.HRC(dizi,dörttebir)

Çalışma sayfasındaki bir hücreye TOPLAMA formülünü girdiğinizde işlev_sayısı bağımsız değişkenini yazar yazmaz bağımsız değişken olarak kullanabileceğiniz tüm işlevlerin listesini görürsünüz.

İkinci bir başv bağımsız değişkeni gerekirse ve verilmemişsi TOPLAMA #DEĞER! hatası verir.

Bir veya daha fazla başvuru 3-B ise, TOPLAMA, #DEĞER! hata değeri verir.

Desteklenen Excel Versiyonu

Excel 2010 Excel 2013 Excel 2016 Excel 2019 Ofis 365

Diziliş Yapısı

işlev_num seçenekler dizi k
#TOPLAMA #AGGREGATE
Üstteki alanda, Google Reklamları yerine sizin reklamınızın yayınlanmasını ister misiniz?
Reklam vermek istiyorum

Daha önce yorum yapılmamış!

#SAYI/0! (#DIV /0!) Hatası

Kurmuş olduğunuz formül ya bir sayıyı sıfıra bölmeye çalışıyor ya da bölme işlemini yapmak için gösterdiğiniz hedef hücrenin içeriği boşttur.

Bu hatayla ilgili daha fazla bilgi için buraya tıklayabilirsiniz.
Yükleniyor...