Çözüldü Koşullu Biçimlendirme Ile Tarih Belirleme

52779' Alıntı:

Selamlar,
Koşullu Biçimlendirmelerde, komple sütun ya da komple satır değerlendirilmesi boş yere performans kaybı olacaktır.
Ayrıca, bu durum, sizin örnekte olduğu gibi, özellikle en yakın olanının biçimlendirilmesi gibi dizi formül gerektirenlerde de kasılmalara yavaşlamalara neden olacaktır.
o nedenle, verilerin oldukları alanlar, koşullu biçimlendirilme uygulanacak alanlar olarak seçildi.

Buna göre,
Durum 1 : Ayın Son günleri
Uygulama Alanı A1 : A112
Formül =A1=SERİAY(A1;0)

Durum2 : Ayın son günü ya da son gününe en yakın
Uygulama Alanı F1 : F112
Formül =VE(F1<>"";MAK(EĞER((AY($F$1:$F$112)=AY(F1))*(YIL($F$1:$F$112)=YIL(F1));$F$1:$F$112))=F1)

Durum 3 : Günü 9 olanlar
Uygulama Alanı K1 : K112
Formül =K1=GÜN(K1)

Durum4 : Günü 9 olan ya da 9 a en yakın olanlar (Her AY-YIL için... Burada 1 kriter daha olmalı. ben Her AY-YIL için olarak belirledim. Aksi halde, Tüm Günler bakılır. 9 varsa onlar renklendirilir. Aksi halde, diyelim ki Mutlak fark olarak en küçük günü 7 olsun, hangi ay olursa olsun günü 7 olanlar renklendirilir.)
Uygulama Alanı P1 : P112
Formül =VE(P1<>"";MİN(EĞER((AY($P$1:$P$112)=AY(P1))*(YIL($P$1:$P$112)=YIL(P1));MUTLAK(GÜN($P$1:$P$112)-9)))=MUTLAK(GÜN(P1)-9))

Dosyanız ektedir... incelersiniz.

Genişletmek için tıklayın ...

52779' Alıntı:

T kolonuna verileri ekledim.
Ve "istenilen tarihten küçük en yakın tarih ten kastınız, Ayın 9 una eşit ya da KÜÇÜK En Yakın
olarak yorumluyorum. Bu durumda

Formül :
=VE(T1<>"";MAK(EĞER((AY($T$1:$T$112)=AY(T1))*(YIL($T$1:$T$112)=YIL(T1))*(GÜN($T$1:$T$112)<=9);$T$1:$T$112))=T1)

Eğer ki, bir tarih belirliyorsunuz örneğin W2 hücresinde 20.02.2022 yazıyor olsun.
Bu tarihe EŞİT ya da KÜÇÜK en Yakın tarih diyorsanız , o zaman Formül
=VE($W$2<>"";T1<>"";MAK(EĞER($T$1:$T$112<=$W$2;$T$1:$T$112))=T1)

Dosyada T kolonunda bu iki biçimlendirmeyi de görebilirsiniz.

Genişletmek için tıklayın ...